BiLauncher/packaging/windows/BiLauncher.iss

; Установщик BiLauncher для Windows (Inno Setup 6).
    ;
; Собирается в CI после `cmake --install`:
                                         ;   iscc /DAppVersion=1.0.0 /DSourceDir=C:\...\stage /DOutputDir=C:\...\dist packaging\windows\BiLauncher.iss
    ; SourceDir — префикс установки: bin\ с BiLauncher.exe и развёрнутым windeployqt Qt,
    ; share\doc\BiLauncher\ с лицензиями.

#ifndef AppVersion
#error Передайте версию: /DAppVersion=X.Y.Z
#endif
#ifndef SourceDir
#error Передайте префикс установки: /DSourceDir=...
#endif
#ifndef OutputDir
#define OutputDir "."
#endif
    ; VersionInfoVersion принимает только числа (X.Y.Z[.W]), поэтому у предрелиза
    ; (1.0.1-rc1) суффикс отрезаем; полная версия идёт в текстовые поля.
#if Pos("-", AppVersion) > 0
#define NumericVersion Copy(AppVersion, 1, Pos("-", AppVersion) - 1)
#else
#define NumericVersion AppVersion
#endif

        [Setup]
    ; AppId не менять между версиями — по нему обновление находит прежнюю установку.
    AppId={{6E0B5C1D-8F2A-4C7E-9B3D-2A1F4E5C7B90}
             AppName=BiLauncher
                 AppVersion={#AppVersion}
             AppVerName=BiLauncher {#AppVersion}
             AppPublisher=GaleonDev
                 AppPublisherURL=https://projects-live.galeonworx.com/galeon/BiLauncher
                     AppSupportURL=https://projects-live.galeonworx.com/galeon/BiLauncher/issues
                         VersionInfoVersion={#NumericVersion}
             VersionInfoTextVersion={#AppVersion}
             VersionInfoProductTextVersion={#AppVersion}
             DefaultDirName={autopf}\BiLauncher
                 DefaultGroupName=BiLauncher
                     DisableProgramGroupPage=yes
                         LicenseFile={#SourceDir}\share\doc\BiLauncher\LICENSE
                             OutputDir={#OutputDir}
             OutputBaseFilename=BiLauncher-{#AppVersion}-win64-setup
                                      SetupIconFile=..\..\icons\icon.ico
                                                         UninstallDisplayIcon={app}\bin\BiLauncher.exe
                                                                                    Compression=lzma2/ultra64
                                                                                                      SolidCompression=yes
                 LZMANumBlockThreads=4
             ArchitecturesAllowed=x64compatible
                 ArchitecturesInstallIn64BitMode=x64compatible
                     PrivilegesRequiredOverridesAllowed=dialog
                         WizardStyle=modern

                                 [Languages]
             Name: "russian"; MessagesFile: "compiler:Languages\Russian.isl"
               Name: "english"; MessagesFile: "compiler:Default.isl"

                       [Tasks]
               Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"

                           [Files]
                   Source: "{#SourceDir}\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs; Excludes: "vc_redist.x64.exe"
#ifexist SourceDir + "\bin\vc_redist.x64.exe"
           Source: "{#SourceDir}\bin\vc_redist.x64.exe"; DestDir: "{tmp}"; Flags: deleteafterinstall
#endif

                [Icons]
        Name: "{autoprograms}\BiLauncher"; Filename: "{app}\bin\BiLauncher.exe"
           Name: "{autodesktop}\BiLauncher"; Filename: "{app}\bin\BiLauncher.exe"; Tasks: desktopicon

                [Run]
#ifexist SourceDir + "\bin\vc_redist.x64.exe"
        Filename: "{tmp}\vc_redist.x64.exe"; Parameters: "/install /quiet /norestart"; StatusMsg: "Установка Microsoft Visual C++ Runtime..."; Flags: waituntilterminated
#endif
            Filename: "{app}\bin\BiLauncher.exe"; Description: "{cm:LaunchProgram,BiLauncher}"; Flags: nowait postinstall skipifsilent